# /etc/cshrc
#
# csh configuration for all shell invocations.

# by default, we want this to get set.
# Even for non-interactive, non-login shells.
[ "`id -gn`" = "`id -un`" -a `id -u` -gt 99 ]
if $status then
   umask 022
else
   umask 002
endif

setenv INTEL /opt/intel/compiler70/ia32
setenv PGI /opt/pgi
setenv PGIBIN /opt/pgi/linux86/bin

if ($?PATH) then
   setenv PATH "${PATH}:/usr/local/bin:$INTEL/bin:/usr/local/intel/bin:$PGI/linux86/bin"
else
   setenv PATH "/bin:/usr/bin:/usr/local/bin:$INTEL/bin:/usr/local/intel/bin:$PGI/linux86/bin"
endif
test -f $INTEL/bin/iccvars.csh && source $INTEL/bin/iccvars.csh

setenv MANPATH "`manpath`:/opt/intel/compiler70/man:/usr/pbs/man:/opt/pgi/man" 

if ($?prompt) then
  if ($?tcsh) then
    set prompt='[%n@%m %c]$ ' 
  else
    set prompt=\[`id -nu`@`hostname -s`\]\$\ 
  endif
endif

if ( -d /etc/profile.d ) then
   set nonomatch
        foreach i ( /etc/profile.d/*.csh )
      if ( -r $i ) then
                     source $i
      endif
        end
   unset i nonomatch
endif

# For FLEX-lm
setenv LM_LICENSE_FILE "/opt/pgi/license.dat"

# Make 'su' use a login shell (workaround for unresolved
# 'LD_LIBRARY_PATH: Undefined variable' problem)
alias su 'su -l'

